You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

293 lines
8.6 KiB

  1. # -*- Autoconf -*-
  2. # Process this file with autoconf to produce a configure script.
  3. AC_PREREQ(2.68)
  4. AC_INIT([GNU Guix],
  5. [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
  6. [bug-guix@gnu.org], [guix],
  7. [https://www.gnu.org/software/guix/])
  8. AC_CONFIG_AUX_DIR([build-aux])
  9. AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  10. color-tests parallel-tests -Woverride -Wno-portability])
  11. # Enable silent rules by default.
  12. AM_SILENT_RULES([yes])
  13. AC_CONFIG_SRCDIR([guix.scm])
  14. AC_CONFIG_MACRO_DIR([m4])
  15. dnl For the C++ code. This must be used early.
  16. AC_USE_SYSTEM_EXTENSIONS
  17. AM_GNU_GETTEXT([external])
  18. AM_GNU_GETTEXT_VERSION([0.18.1])
  19. GUIX_SYSTEM_TYPE
  20. GUIX_ASSERT_SUPPORTED_SYSTEM
  21. AC_ARG_WITH(store-dir,
  22. AC_HELP_STRING([--with-store-dir=PATH],
  23. [file name of the store (defaults to /gnu/store)]),
  24. [storedir="$withval"],
  25. [storedir="/gnu/store"])
  26. AC_SUBST(storedir)
  27. AC_ARG_WITH([bash-completion-dir],
  28. AC_HELP_STRING([--with-bash-completion-dir=DIR],
  29. [name of the Bash completion directory]),
  30. [bashcompletiondir="$withval"],
  31. [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  32. AC_SUBST([bashcompletiondir])
  33. AC_ARG_WITH([zsh-completion-dir],
  34. AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  35. [name of the Zsh completion directory]),
  36. [zshcompletiondir="$withval"],
  37. [zshcompletiondir='${datadir}/zsh/site-functions'])
  38. AC_SUBST([zshcompletiondir])
  39. AC_ARG_WITH([fish-completion-dir],
  40. AC_HELP_STRING([--with-fish-completion-dir=DIR],
  41. [name of the Fish completion directory]),
  42. [fishcompletiondir="$withval"],
  43. [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  44. AC_SUBST([fishcompletiondir])
  45. AC_ARG_WITH([selinux-policy-dir],
  46. AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  47. [name of the SELinux policy directory]),
  48. [selinux_policydir="$withval"],
  49. [selinux_policydir='${datadir}/selinux/'])
  50. AC_SUBST([selinux_policydir])
  51. dnl Better be verbose.
  52. AC_MSG_CHECKING([for the store directory])
  53. AC_MSG_RESULT([$storedir])
  54. AC_ARG_ENABLE([daemon],
  55. [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  56. [guix_build_daemon="$enableval"],
  57. [guix_build_daemon="yes"])
  58. # Prepare a version of $localstatedir & co. that does not contain references
  59. # to shell variables.
  60. guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  61. guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  62. guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  63. guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  64. AC_SUBST([guix_localstatedir])
  65. AC_SUBST([guix_sysconfdir])
  66. AC_SUBST([guix_sbindir])
  67. GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  68. AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  69. dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  70. dnl Make sure they are available.
  71. m4_pattern_forbid([PKG_CHECK_MODULES])
  72. m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  73. m4_pattern_forbid([^GUILE_P$])
  74. dnl Search for 'guile' and 'guild'. This macro defines
  75. dnl 'GUILE_EFFECTIVE_VERSION'.
  76. GUILE_PKG([2.2 2.0])
  77. GUILE_PROGS
  78. if test "x$GUILD" = "x"; then
  79. AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  80. fi
  81. if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  82. PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.13])
  83. fi
  84. dnl Installation directories for .scm and .go files.
  85. guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  86. guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
  87. AC_SUBST([guilemoduledir])
  88. AC_SUBST([guileobjectdir])
  89. dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
  90. dnl pull', among other things.
  91. GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
  92. if test "x$have_gnutls" != "xyes"; then
  93. AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
  94. fi
  95. dnl Check for Guile-Git.
  96. GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
  97. if test "x$have_guile_git" != "xyes"; then
  98. AC_MSG_ERROR([Guile-Git is missing; please install it.])
  99. fi
  100. dnl Guile-JSON is used in various places.
  101. GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  102. AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  103. dnl Guile-Sqlite3 is used by the (guix store ...) modules.
  104. GUIX_CHECK_GUILE_SQLITE3
  105. if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
  106. AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
  107. fi
  108. GUILE_MODULE_AVAILABLE([have_guile_gcrypt], [(gcrypt hash)])
  109. if test "x$have_guile_gcrypt" != "xyes"; then
  110. AC_MSG_ERROR([Guile-Gcrypt could not be found; please install it.])
  111. fi
  112. dnl Make sure we have a full-fledged Guile.
  113. GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  114. dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
  115. dnl found in 2.2.1. See <https://bugs.gnu.org/29903>.
  116. GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
  117. AC_PROG_SED
  118. dnl Decompressors, for use by the substituter and other modules.
  119. AC_PATH_PROG([GZIP], [gzip])
  120. AC_PATH_PROG([BZIP2], [bzip2])
  121. AC_PATH_PROG([XZ], [xz])
  122. AC_SUBST([GZIP])
  123. AC_SUBST([BZIP2])
  124. AC_SUBST([XZ])
  125. AC_ARG_WITH([nix-prefix],
  126. [AS_HELP_STRING([--with-nix-prefix=DIR],
  127. [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
  128. [case "$withval" in
  129. yes|no) ;;
  130. *)
  131. NIX_PREFIX="$withval"
  132. PATH="$NIX_PREFIX/bin:$PATH"; export PATH
  133. AC_SUBST([NIX_PREFIX])
  134. ;;
  135. esac],
  136. [])
  137. AC_PATH_PROG([NIX_HASH], [nix-hash])
  138. if test "x$guix_build_daemon$NIX_HASH" = "xno"; then
  139. AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
  140. fi
  141. AC_ARG_WITH([nixpkgs],
  142. [AS_HELP_STRING([--with-nixpkgs=DIR],
  143. [search for Nixpkgs in DIR (for testing purposes only)])],
  144. [case "$withval" in
  145. yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
  146. *) NIXPKGS="$withval";;
  147. esac],
  148. [])
  149. AC_MSG_CHECKING([for Nixpkgs source tree])
  150. if test -f "$NIXPKGS/default.nix"; then
  151. AC_MSG_RESULT([$NIXPKGS])
  152. AC_SUBST([NIXPKGS])
  153. else
  154. AC_MSG_RESULT([not found])
  155. fi
  156. LIBGCRYPT="libgcrypt"
  157. LIBGCRYPT_LIBDIR="no"
  158. LIBGCRYPT_PREFIX="no"
  159. AC_ARG_WITH([libgcrypt-prefix],
  160. [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
  161. [case "$withval" in
  162. yes|no)
  163. ;;
  164. *)
  165. LIBGCRYPT="$withval/lib/libgcrypt"
  166. LIBGCRYPT_PREFIX="$withval"
  167. LIBGCRYPT_LIBDIR="$withval/lib"
  168. ;;
  169. esac])
  170. AC_ARG_WITH([libgcrypt-libdir],
  171. [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
  172. [search for GNU libgcrypt's shared library in DIR])],
  173. [case "$withval" in
  174. yes|no)
  175. LIBGCRYPT="libgcrypt"
  176. LIBGCRYPT_LIBDIR="no"
  177. ;;
  178. *)
  179. LIBGCRYPT="$withval/libgcrypt"
  180. LIBGCRYPT_LIBDIR="$withval"
  181. ;;
  182. esac])
  183. dnl If none of the --with-libgcrypt-* options was used, try to determine the
  184. dnl the library directory.
  185. case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
  186. xnono)
  187. GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
  188. ;;
  189. esac
  190. dnl Library name suitable for `dynamic-link'.
  191. AC_MSG_CHECKING([for libgcrypt shared library name])
  192. AC_MSG_RESULT([$LIBGCRYPT])
  193. AC_SUBST([LIBGCRYPT])
  194. AC_SUBST([LIBGCRYPT_PREFIX])
  195. AC_SUBST([LIBGCRYPT_LIBDIR])
  196. GUIX_ASSERT_LIBGCRYPT_USABLE
  197. dnl Library name of zlib suitable for 'dynamic-link'.
  198. GUIX_LIBZ_LIBDIR([libz_libdir])
  199. if test "x$libz_libdir" = "x"; then
  200. LIBZ="libz"
  201. else
  202. LIBZ="$libz_libdir/libz"
  203. fi
  204. AC_MSG_CHECKING([for zlib's shared library name])
  205. AC_MSG_RESULT([$LIBZ])
  206. AC_SUBST([LIBZ])
  207. dnl Check for Guile-SSH, for the (guix ssh) module.
  208. GUIX_CHECK_GUILE_SSH
  209. AM_CONDITIONAL([HAVE_GUILE_SSH],
  210. [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
  211. AC_CACHE_SAVE
  212. m4_include([config-daemon.ac])
  213. dnl `dot' (from the Graphviz package) is only needed for maintainers.
  214. dnl See `Building from Git' in the manual for more info.
  215. AM_MISSING_PROG([DOT], [dot])
  216. dnl Manual pages.
  217. AM_MISSING_PROG([HELP2MAN], [help2man])
  218. dnl Documentation translation.
  219. AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
  220. AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
  221. dnl Emacs (optional), for 'etc/indent-package.el'.
  222. AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
  223. AC_SUBST([EMACS])
  224. case "$storedir" in
  225. /gnu/store)
  226. ;;
  227. *)
  228. AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
  229. AC_MSG_WARN([from downloading substitutes from gnu.org.])
  230. ;;
  231. esac
  232. AC_CONFIG_FILES([Makefile
  233. po/guix/Makefile.in
  234. po/packages/Makefile.in
  235. etc/guix-daemon.cil
  236. guix/config.scm])
  237. AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
  238. AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
  239. [chmod +x pre-inst-env])
  240. AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
  241. AC_OUTPUT