You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

295 lines
8.6 KiB

  1. # -*- Autoconf -*-
  2. # Process this file with autoconf to produce a configure script.
  3. AC_PREREQ(2.68)
  4. AC_INIT([GNU Guix],
  5. [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
  6. [bug-guix@gnu.org], [guix],
  7. [https://www.gnu.org/software/guix/])
  8. AC_CONFIG_AUX_DIR([build-aux])
  9. AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  10. color-tests parallel-tests -Woverride -Wno-portability])
  11. # Enable silent rules by default.
  12. AM_SILENT_RULES([yes])
  13. AC_CONFIG_SRCDIR([guix.scm])
  14. AC_CONFIG_MACRO_DIR([m4])
  15. dnl For the C++ code. This must be used early.
  16. AC_USE_SYSTEM_EXTENSIONS
  17. AM_GNU_GETTEXT([external])
  18. AM_GNU_GETTEXT_VERSION([0.18.1])
  19. GUIX_SYSTEM_TYPE
  20. GUIX_ASSERT_SUPPORTED_SYSTEM
  21. AC_ARG_WITH(store-dir,
  22. AC_HELP_STRING([--with-store-dir=PATH],
  23. [file name of the store (defaults to /gnu/store)]),
  24. [storedir="$withval"],
  25. [storedir="/gnu/store"])
  26. AC_SUBST(storedir)
  27. AC_ARG_WITH([bash-completion-dir],
  28. AC_HELP_STRING([--with-bash-completion-dir=DIR],
  29. [name of the Bash completion directory]),
  30. [bashcompletiondir="$withval"],
  31. [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  32. AC_SUBST([bashcompletiondir])
  33. AC_ARG_WITH([zsh-completion-dir],
  34. AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  35. [name of the Zsh completion directory]),
  36. [zshcompletiondir="$withval"],
  37. [zshcompletiondir='${datadir}/zsh/site-functions'])
  38. AC_SUBST([zshcompletiondir])
  39. AC_ARG_WITH([fish-completion-dir],
  40. AC_HELP_STRING([--with-fish-completion-dir=DIR],
  41. [name of the Fish completion directory]),
  42. [fishcompletiondir="$withval"],
  43. [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  44. AC_SUBST([fishcompletiondir])
  45. AC_ARG_WITH([selinux-policy-dir],
  46. AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  47. [name of the SELinux policy directory]),
  48. [selinux_policydir="$withval"],
  49. [selinux_policydir='${datadir}/selinux/'])
  50. AC_SUBST([selinux_policydir])
  51. dnl Better be verbose.
  52. AC_MSG_CHECKING([for the store directory])
  53. AC_MSG_RESULT([$storedir])
  54. AC_ARG_ENABLE([daemon],
  55. [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  56. [guix_build_daemon="$enableval"],
  57. [guix_build_daemon="yes"])
  58. # Prepare a version of $localstatedir & co. that does not contain references
  59. # to shell variables.
  60. guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  61. guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  62. guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  63. guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  64. AC_SUBST([guix_localstatedir])
  65. AC_SUBST([guix_sysconfdir])
  66. AC_SUBST([guix_sbindir])
  67. GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  68. AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  69. dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  70. dnl Make sure they are available.
  71. m4_pattern_forbid([PKG_CHECK_MODULES])
  72. m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  73. m4_pattern_forbid([^GUILE_P])
  74. m4_pattern_allow([^GUILE_PKG_ERRORS])
  75. m4_pattern_forbid([^GUIX_])
  76. dnl Search for 'guile' and 'guild'. This macro defines
  77. dnl 'GUILE_EFFECTIVE_VERSION'.
  78. GUILE_PKG([2.2 2.0])
  79. GUILE_PROGS
  80. if test "x$GUILD" = "x"; then
  81. AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  82. fi
  83. if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  84. PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.13])
  85. fi
  86. dnl Installation directories for .scm and .go files.
  87. guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  88. guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
  89. AC_SUBST([guilemoduledir])
  90. AC_SUBST([guileobjectdir])
  91. dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
  92. dnl pull', among other things.
  93. GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
  94. if test "x$have_gnutls" != "xyes"; then
  95. AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
  96. fi
  97. dnl Check for Guile-Git.
  98. GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
  99. if test "x$have_guile_git" != "xyes"; then
  100. AC_MSG_ERROR([Guile-Git is missing; please install it.])
  101. fi
  102. dnl Check for Guile-JSON.
  103. GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  104. if test "x$have_guile_json" != "xyes"; then
  105. AC_MSG_ERROR([Guile-JSON is missing; please install it.])
  106. fi
  107. dnl Guile-Sqlite3 is used by the (guix store ...) modules.
  108. GUIX_CHECK_GUILE_SQLITE3
  109. if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
  110. AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
  111. fi
  112. GUILE_MODULE_AVAILABLE([have_guile_gcrypt], [(gcrypt hash)])
  113. if test "x$have_guile_gcrypt" != "xyes"; then
  114. AC_MSG_ERROR([Guile-Gcrypt could not be found; please install it.])
  115. fi
  116. dnl Make sure we have a full-fledged Guile.
  117. GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  118. dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
  119. dnl found in 2.2.1. See <https://bugs.gnu.org/29903>.
  120. GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
  121. AC_PROG_SED
  122. dnl Decompressors, for use by the substituter and other modules.
  123. AC_PATH_PROG([GZIP], [gzip])
  124. AC_PATH_PROG([BZIP2], [bzip2])
  125. AC_PATH_PROG([XZ], [xz])
  126. AC_SUBST([GZIP])
  127. AC_SUBST([BZIP2])
  128. AC_SUBST([XZ])
  129. AC_ARG_WITH([nix-prefix],
  130. [AS_HELP_STRING([--with-nix-prefix=DIR],
  131. [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
  132. [case "$withval" in
  133. yes|no) ;;
  134. *)
  135. NIX_PREFIX="$withval"
  136. PATH="$NIX_PREFIX/bin:$PATH"; export PATH
  137. AC_SUBST([NIX_PREFIX])
  138. ;;
  139. esac],
  140. [])
  141. AC_PATH_PROG([NIX_HASH], [nix-hash])
  142. if test "x$guix_build_daemon$NIX_HASH" = "xno"; then
  143. AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
  144. fi
  145. AC_ARG_WITH([nixpkgs],
  146. [AS_HELP_STRING([--with-nixpkgs=DIR],
  147. [search for Nixpkgs in DIR (for testing purposes only)])],
  148. [case "$withval" in
  149. yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
  150. *) NIXPKGS="$withval";;
  151. esac],
  152. [])
  153. AC_MSG_CHECKING([for Nixpkgs source tree])
  154. if test -f "$NIXPKGS/default.nix"; then
  155. AC_MSG_RESULT([$NIXPKGS])
  156. AC_SUBST([NIXPKGS])
  157. else
  158. AC_MSG_RESULT([not found])
  159. fi
  160. LIBGCRYPT="libgcrypt"
  161. LIBGCRYPT_LIBDIR="no"
  162. LIBGCRYPT_PREFIX="no"
  163. AC_ARG_WITH([libgcrypt-prefix],
  164. [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
  165. [case "$withval" in
  166. yes|no)
  167. ;;
  168. *)
  169. LIBGCRYPT="$withval/lib/libgcrypt"
  170. LIBGCRYPT_PREFIX="$withval"
  171. LIBGCRYPT_LIBDIR="$withval/lib"
  172. ;;
  173. esac])
  174. AC_ARG_WITH([libgcrypt-libdir],
  175. [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
  176. [search for GNU libgcrypt's shared library in DIR])],
  177. [case "$withval" in
  178. yes|no)
  179. LIBGCRYPT="libgcrypt"
  180. LIBGCRYPT_LIBDIR="no"
  181. ;;
  182. *)
  183. LIBGCRYPT="$withval/libgcrypt"
  184. LIBGCRYPT_LIBDIR="$withval"
  185. ;;
  186. esac])
  187. dnl If none of the --with-libgcrypt-* options was used, try to determine the
  188. dnl the library directory.
  189. case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
  190. xnono)
  191. GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
  192. ;;
  193. esac
  194. dnl Library name suitable for `dynamic-link'.
  195. AC_MSG_CHECKING([for libgcrypt shared library name])
  196. AC_MSG_RESULT([$LIBGCRYPT])
  197. AC_SUBST([LIBGCRYPT])
  198. AC_SUBST([LIBGCRYPT_PREFIX])
  199. AC_SUBST([LIBGCRYPT_LIBDIR])
  200. dnl Library name of zlib suitable for 'dynamic-link'.
  201. GUIX_LIBZ_LIBDIR([libz_libdir])
  202. if test "x$libz_libdir" = "x"; then
  203. LIBZ="libz"
  204. else
  205. LIBZ="$libz_libdir/libz"
  206. fi
  207. AC_MSG_CHECKING([for zlib's shared library name])
  208. AC_MSG_RESULT([$LIBZ])
  209. AC_SUBST([LIBZ])
  210. dnl Check for Guile-SSH, for the (guix ssh) module.
  211. GUIX_CHECK_GUILE_SSH
  212. AM_CONDITIONAL([HAVE_GUILE_SSH],
  213. [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
  214. AC_CACHE_SAVE
  215. m4_include([config-daemon.ac])
  216. dnl `dot' (from the Graphviz package) is only needed for maintainers.
  217. dnl See `Building from Git' in the manual for more info.
  218. AM_MISSING_PROG([DOT], [dot])
  219. dnl Manual pages.
  220. AM_MISSING_PROG([HELP2MAN], [help2man])
  221. dnl Documentation translation.
  222. AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
  223. AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
  224. dnl Emacs (optional), for 'etc/indent-package.el'.
  225. AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
  226. AC_SUBST([EMACS])
  227. case "$storedir" in
  228. /gnu/store)
  229. ;;
  230. *)
  231. AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
  232. AC_MSG_WARN([from downloading substitutes from gnu.org.])
  233. ;;
  234. esac
  235. AC_CONFIG_FILES([Makefile
  236. po/guix/Makefile.in
  237. po/packages/Makefile.in
  238. etc/guix-daemon.cil
  239. guix/config.scm])
  240. AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
  241. AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
  242. [chmod +x pre-inst-env])
  243. AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
  244. AC_OUTPUT