You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

293 lines
8.6 KiB

  1. # -*- Autoconf -*-
  2. # Process this file with autoconf to produce a configure script.
  3. AC_PREREQ(2.68)
  4. AC_INIT([GNU Guix],
  5. [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
  6. [bug-guix@gnu.org], [guix],
  7. [https://www.gnu.org/software/guix/])
  8. AC_CONFIG_AUX_DIR([build-aux])
  9. AM_INIT_AUTOMAKE([1.14 gnu silent-rules subdir-objects \
  10. color-tests parallel-tests -Woverride -Wno-portability])
  11. # Enable silent rules by default.
  12. AM_SILENT_RULES([yes])
  13. AC_CONFIG_SRCDIR([guix.scm])
  14. AC_CONFIG_MACRO_DIR([m4])
  15. dnl For the C++ code. This must be used early.
  16. AC_USE_SYSTEM_EXTENSIONS
  17. AM_GNU_GETTEXT([external])
  18. AM_GNU_GETTEXT_VERSION([0.18.1])
  19. GUIX_SYSTEM_TYPE
  20. GUIX_ASSERT_SUPPORTED_SYSTEM
  21. AC_ARG_WITH(store-dir,
  22. AC_HELP_STRING([--with-store-dir=PATH],
  23. [file name of the store (defaults to /gnu/store)]),
  24. [storedir="$withval"],
  25. [storedir="/gnu/store"])
  26. AC_SUBST(storedir)
  27. AC_ARG_WITH([bash-completion-dir],
  28. AC_HELP_STRING([--with-bash-completion-dir=DIR],
  29. [name of the Bash completion directory]),
  30. [bashcompletiondir="$withval"],
  31. [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  32. AC_SUBST([bashcompletiondir])
  33. AC_ARG_WITH([zsh-completion-dir],
  34. AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  35. [name of the Zsh completion directory]),
  36. [zshcompletiondir="$withval"],
  37. [zshcompletiondir='${datadir}/zsh/site-functions'])
  38. AC_SUBST([zshcompletiondir])
  39. AC_ARG_WITH([fish-completion-dir],
  40. AC_HELP_STRING([--with-fish-completion-dir=DIR],
  41. [name of the Fish completion directory]),
  42. [fishcompletiondir="$withval"],
  43. [fishcompletiondir='${datadir}/fish/vendor_completions.d'])
  44. AC_SUBST([fishcompletiondir])
  45. AC_ARG_WITH([selinux-policy-dir],
  46. AC_HELP_STRING([--with-selinux-policy-dir=DIR],
  47. [name of the SELinux policy directory]),
  48. [selinux_policydir="$withval"],
  49. [selinux_policydir='${datadir}/selinux/'])
  50. AC_SUBST([selinux_policydir])
  51. dnl Better be verbose.
  52. AC_MSG_CHECKING([for the store directory])
  53. AC_MSG_RESULT([$storedir])
  54. AC_ARG_ENABLE([daemon],
  55. [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  56. [guix_build_daemon="$enableval"],
  57. [guix_build_daemon="yes"])
  58. # Prepare a version of $localstatedir & co. that does not contain references
  59. # to shell variables.
  60. guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  61. guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  62. guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  63. guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  64. AC_SUBST([guix_localstatedir])
  65. AC_SUBST([guix_sysconfdir])
  66. AC_SUBST([guix_sbindir])
  67. GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  68. AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  69. dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  70. dnl Make sure they are available.
  71. m4_pattern_forbid([PKG_CHECK_MODULES])
  72. m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  73. m4_pattern_forbid([^GUILE_P])
  74. m4_pattern_allow([^GUILE_PKG_ERRORS])
  75. m4_pattern_forbid([^GUIX_])
  76. dnl Search for 'guile' and 'guild'. This macro defines
  77. dnl 'GUILE_EFFECTIVE_VERSION'.
  78. GUILE_PKG([2.2 2.0])
  79. GUILE_PROGS
  80. if test "x$GUILD" = "x"; then
  81. AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  82. fi
  83. if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  84. PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.13])
  85. fi
  86. dnl Installation directories for .scm and .go files.
  87. guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  88. guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
  89. AC_SUBST([guilemoduledir])
  90. AC_SUBST([guileobjectdir])
  91. dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
  92. dnl pull', among other things.
  93. GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
  94. if test "x$have_gnutls" != "xyes"; then
  95. AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
  96. fi
  97. dnl Check for Guile-Git.
  98. GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
  99. if test "x$have_guile_git" != "xyes"; then
  100. AC_MSG_ERROR([Guile-Git is missing; please install it.])
  101. fi
  102. dnl Guile-JSON is used in various places.
  103. GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  104. AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  105. dnl Guile-Sqlite3 is used by the (guix store ...) modules.
  106. GUIX_CHECK_GUILE_SQLITE3
  107. if test "x$guix_cv_have_recent_guile_sqlite3" != "xyes"; then
  108. AC_MSG_ERROR([A recent Guile-SQLite3 could not be found; please install it.])
  109. fi
  110. GUILE_MODULE_AVAILABLE([have_guile_gcrypt], [(gcrypt hash)])
  111. if test "x$have_guile_gcrypt" != "xyes"; then
  112. AC_MSG_ERROR([Guile-Gcrypt could not be found; please install it.])
  113. fi
  114. dnl Make sure we have a full-fledged Guile.
  115. GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  116. dnl Make sure we don't suffer from the bug in 'equal?' wrt. syntax objects
  117. dnl found in 2.2.1. See <https://bugs.gnu.org/29903>.
  118. GUIX_ASSERT_SYNTAX_OBJECT_EQUAL
  119. AC_PROG_SED
  120. dnl Decompressors, for use by the substituter and other modules.
  121. AC_PATH_PROG([GZIP], [gzip])
  122. AC_PATH_PROG([BZIP2], [bzip2])
  123. AC_PATH_PROG([XZ], [xz])
  124. AC_SUBST([GZIP])
  125. AC_SUBST([BZIP2])
  126. AC_SUBST([XZ])
  127. AC_ARG_WITH([nix-prefix],
  128. [AS_HELP_STRING([--with-nix-prefix=DIR],
  129. [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
  130. [case "$withval" in
  131. yes|no) ;;
  132. *)
  133. NIX_PREFIX="$withval"
  134. PATH="$NIX_PREFIX/bin:$PATH"; export PATH
  135. AC_SUBST([NIX_PREFIX])
  136. ;;
  137. esac],
  138. [])
  139. AC_PATH_PROG([NIX_HASH], [nix-hash])
  140. if test "x$guix_build_daemon$NIX_HASH" = "xno"; then
  141. AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
  142. fi
  143. AC_ARG_WITH([nixpkgs],
  144. [AS_HELP_STRING([--with-nixpkgs=DIR],
  145. [search for Nixpkgs in DIR (for testing purposes only)])],
  146. [case "$withval" in
  147. yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
  148. *) NIXPKGS="$withval";;
  149. esac],
  150. [])
  151. AC_MSG_CHECKING([for Nixpkgs source tree])
  152. if test -f "$NIXPKGS/default.nix"; then
  153. AC_MSG_RESULT([$NIXPKGS])
  154. AC_SUBST([NIXPKGS])
  155. else
  156. AC_MSG_RESULT([not found])
  157. fi
  158. LIBGCRYPT="libgcrypt"
  159. LIBGCRYPT_LIBDIR="no"
  160. LIBGCRYPT_PREFIX="no"
  161. AC_ARG_WITH([libgcrypt-prefix],
  162. [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
  163. [case "$withval" in
  164. yes|no)
  165. ;;
  166. *)
  167. LIBGCRYPT="$withval/lib/libgcrypt"
  168. LIBGCRYPT_PREFIX="$withval"
  169. LIBGCRYPT_LIBDIR="$withval/lib"
  170. ;;
  171. esac])
  172. AC_ARG_WITH([libgcrypt-libdir],
  173. [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
  174. [search for GNU libgcrypt's shared library in DIR])],
  175. [case "$withval" in
  176. yes|no)
  177. LIBGCRYPT="libgcrypt"
  178. LIBGCRYPT_LIBDIR="no"
  179. ;;
  180. *)
  181. LIBGCRYPT="$withval/libgcrypt"
  182. LIBGCRYPT_LIBDIR="$withval"
  183. ;;
  184. esac])
  185. dnl If none of the --with-libgcrypt-* options was used, try to determine the
  186. dnl the library directory.
  187. case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
  188. xnono)
  189. GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
  190. ;;
  191. esac
  192. dnl Library name suitable for `dynamic-link'.
  193. AC_MSG_CHECKING([for libgcrypt shared library name])
  194. AC_MSG_RESULT([$LIBGCRYPT])
  195. AC_SUBST([LIBGCRYPT])
  196. AC_SUBST([LIBGCRYPT_PREFIX])
  197. AC_SUBST([LIBGCRYPT_LIBDIR])
  198. dnl Library name of zlib suitable for 'dynamic-link'.
  199. GUIX_LIBZ_LIBDIR([libz_libdir])
  200. if test "x$libz_libdir" = "x"; then
  201. LIBZ="libz"
  202. else
  203. LIBZ="$libz_libdir/libz"
  204. fi
  205. AC_MSG_CHECKING([for zlib's shared library name])
  206. AC_MSG_RESULT([$LIBZ])
  207. AC_SUBST([LIBZ])
  208. dnl Check for Guile-SSH, for the (guix ssh) module.
  209. GUIX_CHECK_GUILE_SSH
  210. AM_CONDITIONAL([HAVE_GUILE_SSH],
  211. [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
  212. AC_CACHE_SAVE
  213. m4_include([config-daemon.ac])
  214. dnl `dot' (from the Graphviz package) is only needed for maintainers.
  215. dnl See `Building from Git' in the manual for more info.
  216. AM_MISSING_PROG([DOT], [dot])
  217. dnl Manual pages.
  218. AM_MISSING_PROG([HELP2MAN], [help2man])
  219. dnl Documentation translation.
  220. AM_MISSING_PROG([PO4A_TRANSLATE], [po4a-translate])
  221. AM_MISSING_PROG([PO4A_UPDATEPO], [po4a-updatepo])
  222. dnl Emacs (optional), for 'etc/indent-package.el'.
  223. AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
  224. AC_SUBST([EMACS])
  225. case "$storedir" in
  226. /gnu/store)
  227. ;;
  228. *)
  229. AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
  230. AC_MSG_WARN([from downloading substitutes from gnu.org.])
  231. ;;
  232. esac
  233. AC_CONFIG_FILES([Makefile
  234. po/guix/Makefile.in
  235. po/packages/Makefile.in
  236. etc/guix-daemon.cil
  237. guix/config.scm])
  238. AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
  239. AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
  240. [chmod +x pre-inst-env])
  241. AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
  242. AC_OUTPUT