You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

271 lines
7.9 KiB

  1. # -*- Autoconf -*-
  2. # Process this file with autoconf to produce a configure script.
  3. AC_PREREQ(2.68)
  4. AC_INIT([GNU Guix],
  5. [m4_esyscmd([build-aux/git-version-gen .tarball-version])],
  6. [bug-guix@gnu.org], [guix],
  7. [https://www.gnu.org/software/guix/])
  8. AC_CONFIG_AUX_DIR([build-aux])
  9. AM_INIT_AUTOMAKE([1.12 gnu silent-rules subdir-objects \
  10. color-tests parallel-tests -Woverride -Wno-portability])
  11. # Enable silent rules by default.
  12. AM_SILENT_RULES([yes])
  13. AC_CONFIG_SRCDIR([guix.scm])
  14. AC_CONFIG_MACRO_DIR([m4])
  15. dnl For the C++ code. This must be used early.
  16. AC_USE_SYSTEM_EXTENSIONS
  17. AM_GNU_GETTEXT([external])
  18. AM_GNU_GETTEXT_VERSION([0.18.1])
  19. GUIX_SYSTEM_TYPE
  20. GUIX_ASSERT_SUPPORTED_SYSTEM
  21. AC_ARG_WITH(store-dir,
  22. AC_HELP_STRING([--with-store-dir=PATH],
  23. [file name of the store (defaults to /gnu/store)]),
  24. [storedir="$withval"],
  25. [storedir="/gnu/store"])
  26. AC_SUBST(storedir)
  27. AC_ARG_WITH([bash-completion-dir],
  28. AC_HELP_STRING([--with-bash-completion-dir=DIR],
  29. [name of the Bash completion directory]),
  30. [bashcompletiondir="$withval"],
  31. [bashcompletiondir='${sysconfdir}/bash_completion.d'])
  32. AC_SUBST([bashcompletiondir])
  33. AC_ARG_WITH([zsh-completion-dir],
  34. AC_HELP_STRING([--with-zsh-completion-dir=DIR],
  35. [name of the Zsh completion directory]),
  36. [zshcompletiondir="$withval"],
  37. [zshcompletiondir='${datadir}/zsh/site-functions'])
  38. AC_SUBST([zshcompletiondir])
  39. dnl Better be verbose.
  40. AC_MSG_CHECKING([for the store directory])
  41. AC_MSG_RESULT([$storedir])
  42. AC_ARG_ENABLE([daemon],
  43. [AS_HELP_STRING([--disable-daemon], [do not build the Nix daemon (C++)])],
  44. [guix_build_daemon="$enableval"],
  45. [guix_build_daemon="yes"])
  46. # Prepare a version of $localstatedir & co. that does not contain references
  47. # to shell variables.
  48. guix_prefix="`eval echo $prefix | sed -e"s|NONE|/usr/local|g"`"
  49. guix_localstatedir="`eval echo $localstatedir | sed -e "s|NONE|$guix_prefix|g"`"
  50. guix_sysconfdir="`eval echo $sysconfdir | sed -e "s|NONE|$guix_prefix|g"`"
  51. guix_sbindir="`eval echo $sbindir | sed -e "s|NONE|$guix_prefix|g"`"
  52. AC_SUBST([guix_localstatedir])
  53. AC_SUBST([guix_sysconfdir])
  54. AC_SUBST([guix_sbindir])
  55. GUIX_CHECK_FILE_NAME_LIMITS([can_run_tests])
  56. AM_CONDITIONAL([CAN_RUN_TESTS], [test "x$can_run_tests" = "xyes"])
  57. dnl We require pkg.m4 (from pkg-config) and guile.m4 (from Guile.)
  58. dnl Make sure they are available.
  59. m4_pattern_forbid([PKG_CHECK_MODULES])
  60. m4_pattern_forbid([GUILE_MODULE_AVAILABLE])
  61. m4_pattern_forbid([^GUILE_P$])
  62. dnl Search for 'guile' and 'guild'. This macro defines
  63. dnl 'GUILE_EFFECTIVE_VERSION'.
  64. GUILE_PKG([2.2 2.0])
  65. GUILE_PROGS
  66. if test "x$GUILD" = "x"; then
  67. AC_MSG_ERROR(['guild' binary not found; please check your guile-2.x installation.])
  68. fi
  69. if test "x$GUILE_EFFECTIVE_VERSION" = "x2.0"; then
  70. PKG_CHECK_MODULES([GUILE], [guile-2.0 >= 2.0.9])
  71. fi
  72. dnl Installation directories for .scm and .go files.
  73. guilemoduledir="${datarootdir}/guile/site/$GUILE_EFFECTIVE_VERSION"
  74. guileobjectdir="${libdir}/guile/$GUILE_EFFECTIVE_VERSION/site-ccache"
  75. AC_SUBST([guilemoduledir])
  76. AC_SUBST([guileobjectdir])
  77. dnl The GnuTLS bindings are necessary for substitutes over HTTPS and for 'guix
  78. dnl pull', among other things.
  79. GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
  80. if test "x$have_gnutls" != "xyes"; then
  81. AC_MSG_ERROR([The Guile bindings of GnuTLS are missing; please install them.])
  82. fi
  83. dnl Check for Guile-Git.
  84. GUILE_MODULE_AVAILABLE([have_guile_git], [(git)])
  85. if test "x$have_guile_git" != "xyes"; then
  86. AC_MSG_ERROR([Guile-Git is missing; please install it.])
  87. fi
  88. dnl Guile-JSON is used in various places.
  89. GUILE_MODULE_AVAILABLE([have_guile_json], [(json)])
  90. AM_CONDITIONAL([HAVE_GUILE_JSON], [test "x$have_guile_json" = "xyes"])
  91. dnl Make sure we have a full-fledged Guile.
  92. GUIX_ASSERT_GUILE_FEATURES([regex posix socket net-db threads])
  93. dnl Decompressors, for use by the substituter and other modules.
  94. AC_PATH_PROG([GZIP], [gzip])
  95. AC_PATH_PROG([BZIP2], [bzip2])
  96. AC_PATH_PROG([XZ], [xz])
  97. AC_SUBST([GZIP])
  98. AC_SUBST([BZIP2])
  99. AC_SUBST([XZ])
  100. AC_ARG_WITH([nix-prefix],
  101. [AS_HELP_STRING([--with-nix-prefix=DIR],
  102. [search for Nix in DIR (for testing purposes and '--disable-daemon' builds)])],
  103. [case "$withval" in
  104. yes|no) ;;
  105. *)
  106. NIX_PREFIX="$withval"
  107. PATH="$NIX_PREFIX/bin:$PATH"; export PATH
  108. AC_SUBST([NIX_PREFIX])
  109. ;;
  110. esac],
  111. [])
  112. AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
  113. AC_PATH_PROG([NIX_HASH], [nix-hash])
  114. if test "x$guix_build_daemon$NIX_INSTANTIATE$NIX_HASH" = "xno"; then
  115. AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
  116. fi
  117. if test "x$NIX_INSTANTIATE" = "x"; then
  118. # This program is an optional dependency, so we just want it to be
  119. # taken from $PATH if it's not available right now.
  120. NIX_INSTANTIATE="nix-instantiate"
  121. fi
  122. AC_ARG_WITH([nixpkgs],
  123. [AS_HELP_STRING([--with-nixpkgs=DIR],
  124. [search for Nixpkgs in DIR (for testing purposes only)])],
  125. [case "$withval" in
  126. yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
  127. *) NIXPKGS="$withval";;
  128. esac],
  129. [])
  130. AC_MSG_CHECKING([for Nixpkgs source tree])
  131. if test -f "$NIXPKGS/default.nix"; then
  132. AC_MSG_RESULT([$NIXPKGS])
  133. AC_SUBST([NIXPKGS])
  134. else
  135. AC_MSG_RESULT([not found])
  136. fi
  137. LIBGCRYPT="libgcrypt"
  138. LIBGCRYPT_LIBDIR="no"
  139. LIBGCRYPT_PREFIX="no"
  140. AC_ARG_WITH([libgcrypt-prefix],
  141. [AS_HELP_STRING([--with-libgcrypt-prefix=DIR], [search for GNU libgcrypt in DIR])],
  142. [case "$withval" in
  143. yes|no)
  144. ;;
  145. *)
  146. LIBGCRYPT="$withval/lib/libgcrypt"
  147. LIBGCRYPT_PREFIX="$withval"
  148. LIBGCRYPT_LIBDIR="$withval/lib"
  149. ;;
  150. esac])
  151. AC_ARG_WITH([libgcrypt-libdir],
  152. [AS_HELP_STRING([--with-libgcrypt-libdir=DIR],
  153. [search for GNU libgcrypt's shared library in DIR])],
  154. [case "$withval" in
  155. yes|no)
  156. LIBGCRYPT="libgcrypt"
  157. LIBGCRYPT_LIBDIR="no"
  158. ;;
  159. *)
  160. LIBGCRYPT="$withval/libgcrypt"
  161. LIBGCRYPT_LIBDIR="$withval"
  162. ;;
  163. esac])
  164. dnl If none of the --with-libgcrypt-* options was used, try to determine the
  165. dnl absolute file name of libgcrypt.so.
  166. case "x$LIBGCRYPT_PREFIX$LIBGCRYPT_LIBDIR" in
  167. xnono)
  168. GUIX_LIBGCRYPT_LIBDIR([LIBGCRYPT_LIBDIR])
  169. if test "x$LIBGCRYPT_LIBDIR" != x; then
  170. LIBGCRYPT="$LIBGCRYPT_LIBDIR/libgcrypt"
  171. else
  172. dnl 'config-daemon.ac' expects "no" in this case.
  173. LIBGCRYPT_LIBDIR="no"
  174. fi
  175. ;;
  176. esac
  177. dnl Library name suitable for `dynamic-link'.
  178. AC_MSG_CHECKING([for libgcrypt shared library name])
  179. AC_MSG_RESULT([$LIBGCRYPT])
  180. AC_SUBST([LIBGCRYPT])
  181. AC_SUBST([LIBGCRYPT_PREFIX])
  182. AC_SUBST([LIBGCRYPT_LIBDIR])
  183. GUIX_ASSERT_LIBGCRYPT_USABLE
  184. dnl Library name of zlib suitable for 'dynamic-link'.
  185. GUIX_LIBZ_LIBDIR([libz_libdir])
  186. if test "x$libz_libdir" = "x"; then
  187. LIBZ="libz"
  188. else
  189. LIBZ="$libz_libdir/libz"
  190. fi
  191. AC_MSG_CHECKING([for zlib's shared library name])
  192. AC_MSG_RESULT([$LIBZ])
  193. AC_SUBST([LIBZ])
  194. dnl Check for Guile-SSH, for the (guix ssh) module.
  195. GUIX_CHECK_GUILE_SSH
  196. AM_CONDITIONAL([HAVE_GUILE_SSH],
  197. [test "x$guix_cv_have_recent_guile_ssh" = "xyes"])
  198. AC_CACHE_SAVE
  199. m4_include([config-daemon.ac])
  200. dnl `dot' (from the Graphviz package) is only needed for maintainers.
  201. dnl See `Building from Git' in the manual for more info.
  202. AM_MISSING_PROG([DOT], [dot])
  203. dnl Manual pages.
  204. AM_MISSING_PROG([HELP2MAN], [help2man])
  205. dnl Emacs (optional), for 'etc/indent-package.el'.
  206. AC_PATH_PROG([EMACS], [emacs], [/usr/bin/emacs])
  207. AC_SUBST([EMACS])
  208. case "$storedir" in
  209. /gnu/store)
  210. ;;
  211. *)
  212. AC_MSG_WARN([Using a store directory other than '/gnu/store' will prevent you])
  213. AC_MSG_WARN([from downloading substitutes from gnu.org.])
  214. ;;
  215. esac
  216. AC_CONFIG_FILES([Makefile
  217. po/guix/Makefile.in
  218. po/packages/Makefile.in
  219. guix/config.scm])
  220. AC_CONFIG_FILES([scripts/guix], [chmod +x scripts/guix])
  221. AC_CONFIG_FILES([test-env:build-aux/test-env.in], [chmod +x test-env])
  222. AC_CONFIG_FILES([pre-inst-env:build-aux/pre-inst-env.in],
  223. [chmod +x pre-inst-env])
  224. AC_CONFIG_FILES([etc/indent-code.el], [chmod +x etc/indent-code.el])
  225. AC_OUTPUT