You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 
 
 
 

68 lines
1.7 KiB

  1. # -*- Autoconf -*-
  2. # Process this file with autoconf to produce a configure script.
  3. AC_PREREQ(2.68)
  4. AC_INIT([Guix], [0.0], [guile-user@gnu.org])
  5. AC_CONFIG_AUX_DIR([build-aux])
  6. AM_INIT_AUTOMAKE([1.11 gnu silent-rules subdir-objects \
  7. color-tests parallel-tests])
  8. AC_CONFIG_SRCDIR([guix.scm])
  9. AC_CONFIG_MACRO_DIR([m4])
  10. AM_GNU_GETTEXT([external])
  11. AM_GNU_GETTEXT_VERSION([0.18.1])
  12. guilemoduledir="${datarootdir}/guile/site/2.0"
  13. AC_SUBST([guilemoduledir])
  14. AC_CANONICAL_HOST
  15. PKG_CHECK_MODULES([GUILE], [guile-2.0])
  16. AC_PATH_PROG([GUILE], [guile])
  17. AC_PATH_PROG([GUILD], [guild])
  18. AC_ARG_WITH([nix-prefix],
  19. [AS_HELP_STRING([--with-nix-prefix=DIR], [search for Nix in DIR])],
  20. [case "$withval" in
  21. yes|no) ;;
  22. *)
  23. NIX_PREFIX="$withval"
  24. PATH="$NIX_PREFIX/bin:$PATH"; export PATH
  25. AC_SUBST([NIX_PREFIX])
  26. ;;
  27. esac],
  28. [])
  29. AC_PATH_PROG([NIX_INSTANTIATE], [nix-instantiate])
  30. AC_PATH_PROG([NIX_HASH], [nix-hash])
  31. if test "x$NIX_INSTANTIATE$NIX_HASH" = "x"; then
  32. AC_MSG_ERROR([Nix programs not found; please install Nix or use `--with-nix-prefix'.])
  33. fi
  34. AC_ARG_WITH([nixpkgs],
  35. [AS_HELP_STRING([--with-nixpkgs=DIR], [search for Nixpkgs in DIR])],
  36. [case "$withval" in
  37. yes|no) AC_MSG_ERROR([Please use `--with-nixpkgs=DIR'.]);;
  38. *) NIXPKGS="$withval";;
  39. esac],
  40. [])
  41. if test -f "$NIXPKGS/default.nix"; then
  42. AC_MSG_CHECKING([for Nixpkgs source tree])
  43. AC_MSG_RESULT([$NIXPKGS])
  44. AC_SUBST([NIXPKGS])
  45. else
  46. AC_MSG_WARN([Nixpkgs not found; this will prevent most tests from running.])
  47. AC_MSG_WARN([Please use `--with-nixpkgs'.])
  48. fi
  49. AC_CONFIG_FILES([Makefile
  50. po/Makefile.in
  51. guix-build])
  52. AC_CONFIG_COMMANDS([commands-exec], [chmod +x guix-build])
  53. AC_OUTPUT